***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 15, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJA3440-AU  D  G  S
Rg     G    1t    1m
M1      2    1    3    3    DMOS    L=1u   W=1u
.model dmos nmos ( 
+vto = {2.633*((8e-3*(temp-25))+1)}
+kp = {16*((3e-2*(temp-25))+1)}
+rb = 1.106e-2
+theta = 0.2
+tnom = 25
+vmax = 0 
+level = 3)   
Cgs	1t	3	50p	ic = 0
Rd	D	4	1e-3	tc = 1e-3,5e-4
Dds	3	4	dds
Gds  D  S  value = {1.7e-3*(temp-25)*limit((v(G, S)-1.5),0,6.5)*limit(v(D,S),0,12)}
.model dds d( bv = 44  ibv = 0.25e-6  tbv1 = 0.8e-3  m=0.36  cjo=32p  vj=0.8
+is = 7.529e-11
+ n = 1.232
+rs = 5e-2)
e1	1 3 table { v(1t, S) } 
+ ((0, 0)
+  (0.50, 0.50)
+  (1.00, 1.00)
+  (2.00, 2.00)
+  (2.50, 2.50)
+  (3.00, 3.60)
+  (4.00, 4.30)
+  (4.50, 4.50)
+  (5.00, 4.65)
+  (6.00, 4.75)
+  (7.00, 4.85)
+  (8.00, 4.95)
+  (9.00, 5.05)
+  (10.0, 5.15)) 
dbody   3   D    dbody
.model   dbody    d(
+is = 7.529e-11
+ n = 1.232
+rs = 5e-2
+tt = 100n
+vj = 0.8	
+eg = 1 )
ra      4    2    1e-3  tc = 1e-3
rs      3    5    1e-3
ls      5    S   0.0001n
m2     1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos( vto = 0  kp = 10  level = 1 ) 
cgdmax  7    4    10p ic = 0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d( m = 0.3   cjo = 68p   vj = 0.4 )
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
